# Contributor: Paul C. <paulr2787@gmail.com>

_realname=pygraphviz
pkgbase=mingw-w64-python-${_realname}
#pkgname=("${MINGW_PACKAGE_PREFIX}-python2-${_realname}" "${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
pkgname=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
pkgver=1.4rc1
pkgrel=0.0
pkgdesc="Python bindings for graphviz"
arch=('any')
groups=('gramps_fixed')
license=('BSD')
url="https://pygraphviz.github.io/"
makedepends=("${MINGW_PACKAGE_PREFIX}-python3"
             "${MINGW_PACKAGE_PREFIX}-graphviz")
options=('staticlibs' 'strip' '!debug')

source=("https://github.com/pygraphviz/pygraphviz/archive/${_realname}-${pkgver}.tar.gz"
        pygraphviz.patch)
sha256sums=('e6a9b25dc75f1214acdff1ef82bc48c75e55be6c4db3a449abbb5fcea8ec2cf5'
            '4b4d9e614a70699624c494c31d6da8b9e1bd4fab83e032ed9f84ad1eaec8c013')

prepare() {
  plain "Patching setup files ..."
  cd ${_realname}-${_realname}-${pkgver}
  patch -Np1 -i ${srcdir}/pygraphviz.patch
  cd ..

  cd "${srcdir}"
  pwd
  rm -Rf build-${CARCH}
  cp -r ${_realname}-${_realname}-${pkgver} build-${CARCH}
}

build() {
  # Build python 3 module
  cd "${srcdir}/build-${CARCH}"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=;--install-purelib=;--install-data=" \
  ${MINGW_PREFIX}/bin/python3 setup.py build
}

package_python3-pygraphviz() {
  depends=("${MINGW_PACKAGE_PREFIX}-python3"
           "${MINGW_PACKAGE_PREFIX}-graphviz")

  cd "${srcdir}/build-${CARCH}"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=;--install-purelib=;--install-data=" \
  ${MINGW_PREFIX}/bin/python3 setup.py install --prefix=${MINGW_PREFIX#\/} --root="${pkgdir}" --optimize=1 --skip-build
}

package_mingw-w64-i686-python3-pygraphviz() {
  package_python3-${_realname}
}

package_mingw-w64-x86_64-python3-pygraphviz() {
  package_python3-${_realname}
}
